Backing up flows

Flow Classic
1

Hi,
I am backing up the flows in my PROD environment manually by doing an RMB- Export flows on the Server Manager interface (see attached image)
Is there a way of automating this because I won’t be there every day to do it?
Thank you.

Exporting flows
Exporting flows1920×1298 237 KB

2

Hi,

all contents of the Flow server are in the Data folder. If you want to backup everything you could set up a windows server to backup that folder.

If you want to backup just flows then its folders FlowServerObjects and Workflows

image
image935×500 32.9 KB

You could also create a scheduled machine flow to backup your flows (Oh the inception! :slight_smile: ) by using the File Connector and Zip operations / Add folder to zip file and pointing it to the folder you want to backup and creating the name of the destination zip file in flow (with time stamp)

image
image827×754 21.1 KB

Hope this helps!

B R
Ivan

3

Many thanks for the reply. If I use the first option; doing a daily automated backup of the folders FlowServerObjects and Workflows from that Data folder; if that server gets wiped (worst case scenario) is it just a case of dropping that folder into the same location on a different PC that is the Novacura Flow host server?
Then I can fire up Studio and all the flows will be there?
The backup that I perform manually (from my screen cap() results in a single file with an “fzip” extension.

4

Hi,

yes if you take those 2 folders to any server installation (of the same version) and paste it to its FlowServerObjects and Workflows folders, that other server would get all the flows.
One more thing maybe worth backing up would also be the Connectors folder (Connectors dont change that often and if the connector that is used in the flow is not present, studio would make you remap…but still it would be easier if everything matches).

Opening that fzip (in any zip program, this case its 7Zip) shows that it contains FlowServerObjects, Workflows and EnvironmentConfiguration folders

image
image779×250 10 KB

But i personaly never backed up EnvironmentConfiguration folder as it contains only logo, theme and languages data (but you can do that too since its very small)
image

Hope this helps!

B R
Ivan

5

Thanks for the replies. I can’t use a flow to do the backup because I don’t have the FileSystem connector.
I will have to use a Windows task instead and copy the FileServerObjects" and “Workflows” folders.

6

You can automate this process with a batch script…

Please change sitename, basepath, and ncpath to match your environment.

sitename: Your IIS site under which Novacura is running
basepath: Where you want your backups to go
ncpath: The full path to the Novacura directory within the data folder

@echo off
setlocal
set sitename=Default Web Site
set basepath=C:\Users\%username%\backups\Novacura
set ncpath=C:\Novacura\Data\Novacura Flow
goto adminchk

:adminchk
ECHO Checking permissions...
net session >nul 2>&1
if %errorLevel% == 0 (
    goto stopiis
) else (
    goto elevate
)
goto end

:elevate
cls
ECHO Elevating permissions...
powershell -command "Start-Process cmd -ArgumentList '/c cd /d %CD% && %~nx0' -Verb runas"
goto end

:stopiis
ECHO Stopping IIS website...
%windir%\system32\inetsrv\appcmd stop site /site.name:"%sitename%"
ECHO[
goto backup

:backup
for /f "tokens=2-4 delims=/ " %%a in ('date /t') do (
  set _date=%%c%%a%%b
)
for /f "tokens=1-4 delims=/:." %%a in ("%TIME%") do (
  set _time=%%a%%b%%c
)
echo Backing up Novacura...
"C:\Program Files (x86)\Novacura\Flow Server Manager\NovaCura.Flow.Server.ExporterTool.exe" -e "%ncpath%" "%basepath%novacura_%_date%-%_time%.fzip" >NUL 2>&1
ECHO[
ECHO Starting IIS website...
%windir%\system32\inetsrv\appcmd start site /site.name:"%sitename%"
goto end

:end
endlocal
7

Thanks for your reply. I think I have my own backup script working using a batch file.